**פרק 10 - הפעלת תצוגת LCD 16\*2 - 2 שורות 16 תווים**

1. **מבוא**

בפרק זה נפעיל תצוגת גביש נוזלי – LCD - Liquid Crystal Display - של 2 שורות , בכל שורה יש 16 תווים. התצוגה שאותה נפעיל נקראת 1602 ( 16 תווים ב 2 שורות ). חומר תאורטי על תצוגת גביש נוזלי והפעלתה ניתן למצוא באתר : <http://www.arikporat.com/projects/lcd.doc> .

נלמד להפעיל את התצוגה גם עם אותיות באנגלית וגם עם אותיות בעברית . כאשר רוצים להציג תווים בעברית יש לציין ולבדוק בהזמנה /קניה של תצוגת LCD שהתצוגה היא גם באנגלית וגם בעברית !! . תצוגה "רגילה" איננה מציגה תווים בעברית !! התצוגה נראית באיור 1.



איור 1 – תצוגת גביש נוזלי

1. **חומרה - מבנה התצוגה**



**טבלת 1 : ההדקים של תצוגת גביש נוזלי.**

**יש לשים לב: הדקים אלו אופייניים לחלק גדול של התצוגות אך לא לכולן !! במקרים רבים הדקים 1 ו 2 הפוכים . מומלץ לבדוק את דפי הנתונים של יצרן התצוגה שקנית כי ישנם חיבורים נוספים וחיבור מוטעה יכול לגרום נזק לרכיב !!**

**ישנן תצוגות עם 2 הדקים נוספים שמספרם 15 ו 16 . אם מחברים 5 וולט ל 15 ואדמה ל 16 ניתן לראות את הכתוב גם בלילה ( מופעלת לד בכרטיס התצוגה).**

לתצוגת ה LCD יש 14 רגליים (לפעמים יש 16 רגלים - 2 נוספות להפעלת לד כדי לקרא מהתצוגה גם בחושך והם נקראים backlight). ישנם 3 קווי בקרה (RW, RS, EN ), 3 קווי מתח ותאורה (Vo, GND, Vcc) ו- 8 קווי נתונים (DB0-DB7).

Vlc - כניסה זו מאפשרת לקבוע את עוצמת התאורה בה תאיר התצוגה. כאשר "0" זה הארה מרבית . מומלץ לחבר כניסה זו לנגד משתנה על מנת לכוון את עוצמת ההארה בצורה נוחה למסתכל.

GND - הארקה, החיבור לאדמה, "0" של המערכת. בחלק מהתצוגות הדק זה נקרא Vss .

VCC - חיבור מתח הספק החיובי של המערכת 5v. בהרבה תצוגות זה נקרא Vdd .

DB0-DB7 - 8 רגלי נתונים שמשמשים ככניסות/יציאות . בעזרת קווים אלו כותבים פקודות או נתונים לתצוגה. ניתן לבצע קריאה מהתצוגה ולדעת באיזו כתובת נמצא ה AC והאם התצוגה פנויה או לא.סיבית DB7 משמשת בזמן הקריאה מידע על מצבו של הדגל "תצוגה עסוקה" - (Busy Flag). אם ברגל זו יש "1" התצוגה עסוקה ואם "0" אז היא פנויה.

RS – ( Register Select ) – בחירת רגיסטר. תפקיד כניסה זו ל LCD הוא לנווט בין האוגרים הפנימיים בתוך התצוגה. בתוך תצוגת ה LCD ישנם 2 אוגרים: אוגר ההוראות (Instruction Register) ואוגר נתונים (Data Register). כאשר המשתמש רוצה לשלוח לתצוגה הוראות שונות כגון: ניקוי תצוגה, הזזת סימן, הוראות אתחול וכדומה, עליו להורות לתצוגה לפנות לאוגר ההוראות על ידי הוצאת "0" ברגל RS. אך כאשר המשתמש רוצה לשלוח לתצוגה נתונים כלומר רוצה לכתוב תו (מספר, אות וכדומה) יש לשלוח "1" ברגל זו.

RW- ( Read/Write ) – קריאה/כתיבה. זוהי רגל כניסה ל LCD שבעזרתה המשתמש אומר לתצוגה אם הוא רוצה לקרוא מה-LCD (למשל לקרוא Busy Flag כדי לבדוק אם התצוגה פנויה) או לכתוב ל LCD הוראה כלשהי או נתון. כאשר רוצים לכתוב ל LCD קו זה יהיה ב "0" וכאשר ברצוננו לקרוא מהתצוגה קו זה יהיה ב "1".

EN- ( Enable ) – אפשור. זהו קו האפשור של התצוגה. הרגל פעילה בגבוה ! קו זה משמש כנועל של ה- LCD . כאשר במבוא כניסה זו ל- LCD מתקבלת ירידה, ה- LCD לוקח את הנתונים בקווי הנתונים ומעבד אותם. לפיכך, יש להעביר לתצוגה את הנתונים ורק אחר כך לתת דופק ירידה ברגל האפשור EN. כמו כן, יחד עם הנתונים יש לשים בתצוגה לפני הדופק את הרצוי על קווי הבקרה RS ו- RW .

1. **חיבור תצוגת גביש נוזלי אל ארדואינו**

היות וכמות ההדקים של הארדואינו די מוגבלת , נחבר את ערכת הארדואינו לתצוגת הגביש הנוזלי על פי השרטוט הבא שבו הממשק של הנתונים הוא בן 4 ביטים ולא 8 . בצורה כזו חוסכים 4 ביטים לשימושים נוספים. את הדק RW חיברנו לאדמה ולכן נוכל רק לכתוב לתצוגה ולא לקרא ממנה.

**תצוגת גביש נוזלי** **ארדואינו אונו**

1 Gnd

2 Vdd

3 vee (Vlc)

4 RS

5 RW

6 ENable

7 DB0

8 DB1

9 DB2

10 DB3

11 DB4

12 DB5

13 DB6

14 DB7

GND

5v

D8 יציאה דיגיטאלית 8

D9 יציאה דיגיטאלית 9

D4 יציאה דיגיטאלית 4

D5 יציאה דיגיטאלית 5

D6 יציאה דיגיטאלית 6

D7 יציאה דיגיטאלית 7

 אדמה

R=4.7K

שרטוט 1: חיבור ערכת הארדואינו לתצוגת גביש נוזלי

הערה: ישנן תצוגות שבהן 2 הדקים נוספים שמספרם 15 ו 16 . בין הדקים אלו נמצאת דיודה פולטת אור – LED שאפשר יהיה לראות את התצוגה במסך גם בלילה. בדרך כלל הדק 15 מקבל את ה + והדק 16 את המינוס.

1. **תוכנה**

**ספרית הארדואינו לתצוגת גביש נוזלי**

קיימת ספריה הנקראת LiquidCrystal שלה מספר פונקציות לניהול תצוגת גביש נוזלי. הספרייה תומכת בתצוגות שנשלטות על ידי הרכיב HD44870 שקיים ברוב התצוגות ( או מחליף של רכיב זה ) . הפונקציות יכולות לשלוט על תצוגות של 2 או 4 שורות עם כמות תווים של 16, 20 או 24 תווים. נזכיר את החשובות שבהן : התחביר האומר איזה הדק בארדואינו מתחבר לאיזה הדק בתצוגה הוא :

LiquidCrystal(rs, enable, d4, d5, d6, d7)
LiquidCrystal(rs, rw, enable, d4, d5, d6, d7)
LiquidCrystal(rs, enable, d0, d1, d2, d3, d4, d5, d6, d7)
LiquidCrystal(rs, rw, enable, d0, d1, d2, d3, d4, d5, d6, d7)

rs - כאן מציינים מהו מספר ההדק הדיגיטאלי בארדואינו המתחבר להדק RS של התצוגה, הקובע האם שולחים פקודה ( או קוראים סטאטוס) ואז נשים 0 או שולחים (או מקבלים ) נתון ואז שמים ברגל 1 ).

rw - כאן מציינים מהו מספר ההדק הדיגיטאלי בארדואינו המתחבר להדק RW של התצוגה. אם חיברנו את הרגל הזו בתצוגה לאדמה ( רק כותבים לתצוגה ולא קוראים ממנה ) אז לא רושמים כאן כלום.

enable - כאן מציינים מהו מספר ההדק הדיגיטאלי בארדואינו המתחבר להדק ENABLE של התצוגה.

d0, d1, d2, d3, d4, d5, d6, d7 – מספרי ההדקים הדיגיטאליים ( בהתאמה) בארדואינו המתחברים אל ההדקים של הנתון המתאימים בתצוגה. ניתן לא לרשום את 4 ההדקים d0,d1,d2,d3 בתצוגות המתחברות בממשק של 4 ביט ולא 8 . במקרה זה ההתחברות היא עם 4 ההדקים הגבוהים ( d4 עד d7 ).

לדוגמה : מחברים תצוגת LCD בממשק של 4 הדקים ורק כותבים לתצוגה ( הדק rw מחובר לאדמה).

הדק דיגיטאלי 8 מתחבר לרגל rs . הדק דיגיטאלי 9 לרגל enable והדקים 4 עד 7 לרגלים d4 עד d7.

**תכנית א : הדפסה בתצוגה**

#include <LiquidCrystal.h>// LCD הכללת קובץ כותר המכיל הצהרות על פונקציות תצוגת

LiquidCrystal lcd(8, 9, 4, 5, 6, 7); // קביעת ההדקים המתחברים בין הארדואינו לתצוגה

void setup()
{
  lcd.begin(16,1); // פונקציה להפעלת התצוגה עם 16 תווים ושורה אחת בלבד
  lcd.print("Hello World"); // הדפסה לתצוגה
}

void loop() {}

**תכנית ב : הוצאת הודעה לתצוגה וספירה של הזמן בשניות מרגע הפעלת התכנית.**

#include <LiquidCrystal.h> // LCD הכללת קובץ כותר המכיל הצהרות על פונקציות תצוגת

LiquidCrystal lcd(8, 9, 4, 5, 6, 7); // קביעת ההדקים המתחברים בין לוח הארדואינו לתצוגה

void **setup**() {
   lcd.begin(16, 2); // קובעים שמתחברים לתצוגה של 2 שורות 16 תווים
   lcd.print(" arikporat.com"); // הדפסת ההודעה
}

void **loop**() {

  lcd.setCursor(0, 1); // קביעת מיקום הסמן בשורה השנייה ( השורה הראשונה היא 0 ) במיקום 0
/\*

 זימון של הפונקציה millis שנותנת כל שנייה את הזמן באלפיות שנייה ( לכן מחלקים ב 1000 ) והצגת הזמן בתצוגה

\*/

 lcd.print(millis()/1000);

}

1. **פונקציות השייכות לספריה LiquidCrystal**
2. הפונקציה lcd.begin ( )

lcd.begin(cols, rows)

הפונקציה מאתחלת את התצוגה. בעזרת cols קובעים כמה עמודות (תווים) יש בתצוגה ( 16 בדוגמה שלנו ) ובעזרת rows קובעים כמה שורות. זוהי הפונקציה הראשונה שנקרא לה לפני כל שימוש בפונקציה אחרת.

1. הפונקציה lcd.print ( ) . הפונקציה מדפיסה טקסט לתצוגה. ישנן 2 אפשרויות :
2. lcd.print(data)
3. lcd.print(data, BASE)

#### lcd הוא משתנה מטיפוס LiquidCrystal .

**data** הנתון שאותו רוצים להדפיס . הנתון יכול להיות מטיפוס תווי – char , ביית – byte , שלם – int , ארוך – long , או מחרוזת .

BASE – (אופציונלי ) : הבסיס שבו רוצים להדפיס לתצוגה. BIN - בינארי , DEC – עשרוני , OCT – אוקטלי (בסיס 8 ) , HEX – בסיס הקסה דצימאלי .

הפונקציה מחזירה את כמות הבתים שנכתבו לתצוגה ( לא חובה לקבל נתון זה ).

1. הפונקציה **setCursor ( )** . קובעת את מיקום הסמן .

**lcd*.setCursor(col, row)***

בעזרת **col** קובעים את מיקום התו (בין 0 ל 15 במקרה של תצוגה של 16 תווים ) ובעזרת **row** קובעים את השורה . יש **לשים לב** ששורה ראשונה מספרה 0 והשורה השנייה מספרה 1 !!

קיימות פונקציות נוספות הרשומות להלן. כדי לדעת להשתמש בהן יש ללחוץ על מקש ctrl ובעזרת העכבר על הכותרת המתאימה. הלחיצה תביא אותך לאתר של ארדואינו ותוכל לקבל הסבר מדויק.

* [Liquid Crystal Library](http://arduino.cc/en/Reference/LiquidCrystal)
* [Blink](http://arduino.cc/en/Tutorial/LiquidCrystalBlink): control of the block-style cursor.
* [Cursor](http://arduino.cc/en/Tutorial/LiquidCrystalCursor): control of the underscore-style cursor.
* [Display](http://arduino.cc/en/Tutorial/LiquidCrystalDisplay): quickly blank the display without losing what's on it.
* [TextDirection](http://arduino.cc/en/Tutorial/LiquidCrystalTextDirection): control which way text flows from the cursor.
* [Scroll](http://arduino.cc/en/Tutorial/LiquidCrystalScroll): scroll text left and right.
* [Serial input](http://arduino.cc/en/Tutorial/LiquidCrystalSerial): accepts serial input, displays it.
* [SetCursor](http://arduino.cc/en/Tutorial/LiquidCrystalSetCursor): set the cursor position.
* [Autoscroll](http://arduino.cc/en/Tutorial/LiquidCrystalAutoscroll): shift text right and left.
1. **פונקציות עצמאיות מפורטות בשפת C להפעלת תצוגת גביש נוזלי**

נרשום תכנית הכוללת את כל הפונקציות בפירוט ,

התכנית תציג בתצוגה 2 הודעות לסירוגין בהפרש של שנייה וחצי בין הודעה להודעה. אחת באנגלית ולאחריה הודעה בעברית.

ההודעה באנגלית תציג HelloWorld בשורה הראשונה ו arikporat.com בשורה השנייה.

ההודעה בעברית תציג בשורה הראשונה "שלום עולם מהאתר" ובשורה השנייה תציג "של אריק פורת".

בתכנית השתמשנו בפקודות הפועלות על פורט. נזכיר בקצרה את הכללים לגבי הפעלה כפורט :

כל אחד מהפורטים B עד D נשלט על ידי 3 רגיסטרים (אוגרים), שמוגדרים כמשתנים בשפת הארדואינו.

1. אוגר DDR קובע האם ההדק כניסה או יציאה. DDR הוא Data Direction Register – או אוגר כיוון הנתון ( האם כניסה –קלט או יציאה – פלט ).
2. אוגר ה PORT יקבע האם בהדק יהיה HIGH או LOW (גבוה – '1' או נמוך '0' ).
3. אוגר ה PIN הקורא את מצב הדקי הכניסה בעזרת הפונקציה pinMode ( ) .

לאוגרים DDR ו PORT ניתן לכתוב או לקרא. מהאוגר PIN ניתן רק לקרא.

מכאן שיש לנו DDRB DDRC ו DDRB שקובעים מה יהיה מצב כל אחד מההדקים שלהם (כניסה (0) או יציאה (1 ) . לדוגמה: הפקודה DDRD = B11111100 קובעת את ההדקים של פורט D מ D0 ו 1D כקלט וההדקים הגבוהים מ D2 ועד D7 כפלט.

לגבי ההודעה בעברית : יש לשים לב לדברים הבאים:

א. שהתצוגה "יודעת" לכתוב גם עברית !!

1. שההודעה בעברית נכתבת עם תווים בודדים הנרשמים בין גרשים עם פסיק בין תו לתו. בתו האחרון יש לשים 0 (NULL) .
2. קיים הבדל בין האסקי של מעבד התמלילים של הארדואינו ובין האסקי של תצוגת ה LCD . במעבד התמלילים של הארדואינו התו 'א' נרשם כ 90H , 'ב' – 91H וכך הלאה . בתצוגת ה LCD התו 'א' הוא A0H , התו 'ב' הוא A1H וכך הלאה. לכן בפונקציה המוציאה תו לתצוגה lcdData() בדקנו האם התו גדול מ 80H , ואם כן הוספנו 10H שזה ההפרש בין מעבד התמלילים של הארדואינו ובין ה LCD .

יצרן ה LCD נותן את האתחול הבא עבור חיבור עם ממשק של 4 ביט :



ניתן לראות שיש לשלוח לתצוגה 3 פעמים את הערך 3 שהוא Function Set עם השהיה בין פקודה אחת לשנייה. אח"כ יש לשלוח Function Set (אנחנו נשלח 28H ) , אח"כ שולחים Display Off, ClearDisplay , Entry Mode Set ולבסוף Display ON .

התכנית הבאה מתאימה לחיבור ההדקים המופיע בשרטוט 1 .

כאשר כותבים בעברית בארדואינו אז עורך המסך שלו מכניס תווים נוספים ליד כל תו בעברית. לכן בתכנית נבדוק האם התו בעברית. אם כן נציג אותו ועם התו גדול מהערך של העברית – לא נציג אותו.

// ------ ‎הגדרות לתצוגת הגביש הנוזלי‎ -------------‎

#define FunctionSet 3 // על פי הוראות יצרן

#define FourBitsFunctionSet 0x28 // ממשק של 4 ביט , 2 שורות כל תו 7\*5

#define DisplayOff 0x08 // כיבוי התצוגה

#define DisplayOn 0x0f // הדלקת התצוגה , הסמן , סמן מהבהב

#define ClearLcd 1 // ניקוי התצוגה והחזרת הסמן לראשית

#define EnglishEntryMode 6 // קידום מונה כתובות ואין הזזה של התצוגה

#define HebrewEntryMode 4 // הורדה ממונה הכתובות ואין הזז של התצוגה

#define FirstLine 0x80 // מיקום מונה הכתובות בכתובת 0 שהיא תחילת שורה ראשונה

#define SecondLine 0xc0 // תחילת השורה השנייה בתצוגה

#define RS 8 // הדק בחירה בין פקודה - 0 לבין נתון - 1

#define ENABLE 9 // הדק האפשור של התצוגה . מעלים ל 1 ומורידים ל 0

// המחרוזות שיוצגו במסך תצוגת הגביש ----

unsigned char str1[]= "Hello World from arikporat.com ";

unsigned char str2[]= "שלום עולם מהאתר של אריק פורת ";

// -------- תכנית אתחול - קביעת מצב הדקים-------

void setup()

{

 DDRD = B11111111;

 pinMode(RS,OUTPUT);

 pinMode(ENABLE,OUTPUT);

 initLcd();

}

// ------ התכנית הראשית המתבצעת בלולאה אין סופית ---

void loop()

{

 lcdDisplay(str1,0); // הצגת המחרוזת באנגלית

 delay(1500); // השהייה של 1.5 שניות

 lcdDisplay(str2,1); // הצגת המחרוזת בעברית

 delay(1500);

}

// ----- פונקציה לאתחול התצוגה ----

void initLcd()

{

 for(int i=0;i<3;i++)

 {

 PORTD=FunctionSet;

 digitalWrite(RS,0);

 digitalWrite(ENABLE,1);

 digitalWrite(ENABLE,0);

 }

 lcdCommand(FourBitsFunctionSet);

 lcdCommand(DisplayOff);

 lcdCommand(ClearLcd);

 lcdCommand(EnglishEntryMode);

 lcdCommand(DisplayOn);

}

// ----- פונקציה המוציאה פקודה לתצוגה ----

void lcdCommand(unsigned char command)

{

 PORTD=command ; // שליחה של הביטים הגבוהים מ 4 עד 7

 digitalWrite(RS,0); // מראה שמוציאים פקודה

 digitalWrite(ENABLE,1);

 digitalWrite(ENABLE,0);

 PORTD=command<<4; // הזזת הביטים הנמוכים ארבע פעמים

 digitalWrite(ENABLE,1);

 digitalWrite(ENABLE,0);

 delay(5);

}

//---- פונקציה המוציאה נתון לתצוגה --

void lcdData(unsigned char data1)

{

 digitalWrite(RS,1); // מראה שמוציאים נתון

 if(data1>0x80) // האם הנתון בעברית ?

 data1=data1+0x10; // התאמה בין אסקי מעבד תמלילים לאסקי התצוגה

 PORTD=data1;

 digitalWrite(ENABLE,1);

 digitalWrite(ENABLE,0);

 PORTD=data1<<4;

 digitalWrite(ENABLE,1);

 digitalWrite(ENABLE,0);

 delay(1);

}

// ---- פונקציה להוצאת 32 תווים לתצוגה באנגלית ---

void lcdDisplay(unsigned char \*ptr, bool HebrewEnglish)

{

 int i=0;

 lcdCommand(ClearLcd);

 if (HebrewEnglish) // האם ההודעה בעברית ?

 {

 lcdCommand(HebrewEntryMode); // שמונה הכתובות ייחסר אחד כדי לכתוב בעברית

 lcdCommand(FirstLine+15); // העברת הסמן לקצה הימני בשורה הראשונה

 }

 else

 lcdCommand(EnglishEntryMode); // הבאת הסמן לתחילת השורה השנייה

 for(unsigned char \*ptr1=ptr; \*ptr1; ptr1++)

 {

 if(\*ptr1<0xab) // האם התווים בעברית ?

 {

 i++;

 lcdData(\*ptr1);

 }

 if(i == 16) // האם רשמנו 16 תווים ?

 {

 if(HebrewEnglish)

 lcdCommand(SecondLine+15); // הבאת הסמן לקצה הימני של שורה שנייה

 else

 lcdCommand(SecondLine); // 0xc0 - לעבור לשורה השנייה

 }

 }

}

1. **תרגול**
	1. רשום תכנית שתציג בתצוגת הגביש הנוזלי את שמך בשורה הראשונה ואת בית הספר שאתה לומד בשורה השנייה. התצוגה תהיה באנגלית.
	2. רשום את התכנית שבשאלה הקודמת אבל התצוגה תהיה בעברית.
	3. רשום תכנית שתציג את ההודעה שבשאלה א ואת ההודעה שבשאלה ב לסירוגין בהפרש של שנייה וחצי.
	4. רשום תכנית שתציג בשורה ראשונה את שמך בעברית ובשורה השנייה היא תציג את הזמן בשניות מרגע שהפעלת את התכנית. העזר בפונקציה millis() . פונקציה זו מחזירה את מספר אלפיות השנייה מאז שהתחלנו להריץ את התכנית.